日曜デジタル

---

PS/2の規格は、簡単にまとめるとこんな感じ。

• 信号は「クロック」「データ」の２本で、クロックはデバイス側から送られる。
  
• デバイスからのデータはクロックの立下りのタイミングで送られる。
  
• データは、
  「１ビットの０（スタートビット）」
  「８ビットのデータ（LSBから送受信）」
  「１ビットのパリティ」
  「１ビットの１（ストップビット）」
  の合計11ビットで送られる。
  

また、キーボードに限っては

• キーを押したときはキーコードを送り、キーを離したときは"F0"を送ってからキーコードを送る。
  

という決まりがある。

英語が苦にならないなら、Simple PS/2 Interfaceを一読するとよい。

---

なお、PS/2には電圧が5Vの規格と3.3Vの規格があるようだ。
Spartan3スタータキットのマニュアルによると、最近のPS/2デバイスは3.3Vでも動作するが、古いものだと5Vでなければ動作しないことがあるとのこと。

スタータキットの初期設定は3.3Vになっているが、PS/2コネクタのそばのジャンパで5Vに切り替えることができる。
私の手持ちのキーボードは3.3Vでは動作しなかったので、5Vの設定に変えた。

---

さて、回路のほうの動作はこんな感じだ。

• PS/2クロックの立下りを検出する。
  回路全体をPS/2クロックに同期させてしまえば楽だが、外部クロックに同期して動かすのはよろしくないとこちらに書いてあったりしたので、システムクロックで動作させることにした。
  システムクロックを使ってPS/2クロックをサンプリングし、直前の状態と比較することで立下りを検出する。
  
• 受信回路は二つの状態「受信中」「アイドリング」を遷移する。
  
• アイドリングから受信中へ状態遷移するタイミングは、スタートビットが来た時、つまりクロックの立下りでデータが0という条件を満たしたとき。
  
• 受信中はクロック信号に合わせてデータ信号をシフトレジスタに格納していく。データの送信順はLSBからなので、シフトは左から右。
  
• 受信中からアイドリングへ状態遷移するタイミングは、ストップビットを確認したときだが、これはスタートビットを1ビット目として、11ビット目を受信したとき。また、その11ビット目は必ず１であるはず。
  

---

受信中→アイドリングの遷移の判断をするために、10ビット長のシフトレジスタを使った。
スタートビットが来た時点ではシフトレジスタの初期値を次のように設定する。

０１１１１１１１１１

これが、データを４ビット受信した時点ではこんな感じになり

ＸＸＸＸ０１１１１１

８ビットのデータとパリティ（P)を受信した時点では以下のようになる。

ＰＸＸＸＸＸＸＸＸ０

つまり、ＬＳＢが０になったときにストップビットが来るはず。

---

というわけで実際に作ってみたものを最後に載せておく。
ストップビットが来なかったら？　などの異常系の処理や、パリティのチェックなども全くしていないが、とりあえず動く様子は確認できる。

PS/2キーボードを接続してキーを押すと、それに応じて８個のLEDのパターンが変化する。
また、キーを離した瞬間、一瞬１１１１００００が点灯しているのも目視できるはず。
キーのスキャンコードの一覧は、Spartan3スタータキットの薄いほうのマニュアルに載っている。（英語配列キーボード版だけど）

今回、デバッグにはModelSimもちょっと使った。
ソースコードの変更をModelSim側に反映させるやり方がわからなかったので、変更するたびにModelSimの終了→立ち上げを行ってすこぶる面倒くさい。
でも、デバッグには役立った。
テストベンチコードはスマートに書ければ良かったんだけど、11ビット分のデータを送るためのシステムクロック／PS/2クロック／PS/2データの代入文が延々と並んでいるだけなので、割愛する。

---

ＶＨＤＬファイル：

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.STD_LOGIC_ARITH.ALL;
use IEEE.STD_LOGIC_UNSIGNED.ALL;

entity ps2read is
    Port ( clk : in std_logic;
           reset : in std_logic;
           ps2clk : in std_logic;
           ps2data : in std_logic;
           scancode : out std_logic_vector(7 downto 0));
end ps2read;

architecture Behavioral of ps2read is

signal ps2clk_last1 : std_logic;
signal ps2clk_last2 : std_logic;
signal shift_reg : std_logic_vector(9 downto 0);
Type State_t is (Idle, Shifting);
signal state : State_t;

begin
  process(clk, reset)
  begin
    if(reset = '1') then
      state <= Idle;
      scancode <= "00000000";
    elsif(clk'event and clk = '1') then
      ps2clk_last2 <= ps2clk_last1;
      ps2clk_last1 <= ps2clk;

      if (ps2clk_last2 = '1' and ps2clk_last1 = '0') then  -- ps2clk fall edge

        case state is
        when Idle =>
          if (ps2data = '0') then	 -- start bit has come
            state <= Shifting;
            shift_reg <= "0111111111";
          end if;

        when Shifting =>
          if (shift_reg(0) = '0' and ps2data = '1') then	 -- stop bit has come
            scancode <= shift_reg(8 downto 1);
            state <= Idle;
          else
            shift_reg <= ps2data & shift_reg(shift_reg'high downto 1);
          end if;

        when Others =>
          state <= Idle;
        end case;
      end if;
    end if;
  end process;
end Behavioral;

---

UCFファイル：

### Spartan-3 Clock Oscillator:
NET clk LOC=T9; # CLK - 50MHz oscillator

NET reset LOC=M13; # BTN1 (active high)

### Spartan-3 Discrete LEDs:
NET scancode<7> LOC=P11; # LD7 (active high)
NET scancode<6> LOC=P12; # LD6 (active high)
NET scancode<5> LOC=N12; # LD5 (active high)
NET scancode<4> LOC=P13; # LD4 (active high)
NET scancode<3> LOC=N14; # LD3 (active high)
NET scancode<2> LOC=L12; # LD2 (active high)
NET scancode<1> LOC=P14; # LD1 (active high)
NET scancode<0> LOC=K12; # LD0 (active high)

### Spartan-3 PS/2 Port:
NET ps2clk LOC=M16; # PS/2 port clock
NET ps2data LOC=M15; # PS/2 port data